home *** CD-ROM | disk | FTP | other *** search
/ START Magazine / START VOL 4 NO 1.st / POGOSRC.ARC / STPOLAR.ASM < prev    next >
Encoding:
Assembly Source File  |  1985-11-20  |  2.7 KB  |  161 lines
  1.  
  2.     public _sin_tab
  3.  
  4.  
  5.     ;    rot_points(theta, source, dest, count)
  6.     ;        returns source point rotated byt theta in dest
  7.     public    _rot_points
  8. firstp    set    4+4*4
  9. theta    set firstp
  10. source    set    firstp+2
  11. dest    set firstp+6
  12. count    set firstp+10
  13. _rot_points
  14.     movem.l    d3/d4/d5/d6,-(sp)
  15.     move.w    theta(sp),d0
  16.     and.w    #$3ff,d0    ; mod theta by two-pi = 1024
  17.     move.l    #_sin_tab,a0    ; load up sine table
  18.  
  19.     move.l    #quadtable,a1    ; and jump to routine to get sine, cos for quadrant
  20.     move.w    d0,d1
  21.     and.w    #$300,d1
  22.     lsr.w    #6,d1
  23.     move.l    0(a1,d1.w),a1
  24.     jsr        (a1)            ; sine now in d0, cos in d1
  25.  
  26.     move.l    source(sp),a0
  27.     move.l    dest(sp),a1
  28.     move.w    count(sp),d2
  29.     bra        zrp_loop
  30. rp_loop
  31.     move.w    (a0)+,d3
  32.     move.w    (a0)+,d4
  33.  
  34.     move.w    d3,d5
  35.     muls    d1,d5
  36.     asl.l    #2,d5
  37.     swap    d5 
  38.     move.w    d4,d6
  39.     muls    d0,d6
  40.     asl.l    #2,d6
  41.     swap    d6
  42.     add.w    d5,d6
  43.     move.w    d6,(a1)+    ; d->x = itmult(x,co) + itmult(y,si)
  44.  
  45.     muls    d1,d4
  46.     asl.l    #2,d4
  47.     swap    d4
  48.     neg.w    d3
  49.     muls    d0,d3
  50.     asl.l    #2,d3
  51.     swap    d3
  52.     add.w    d4,d3
  53.     move.w    d3,(a1)+     ; d->y = itmult(y,co) + itmult(x,-si)
  54.  
  55. zrp_loop    dbra    d2,rp_loop
  56.     movem.l    (sp)+,d3/d4/d5/d6
  57.     rts
  58.  
  59.     ;    isin(theta)
  60.     ;        returns scaled integer sine of theta
  61.     public _isin
  62. _isin
  63.     bsr isincos
  64.     rts
  65.  
  66.     public _icos
  67. _icos
  68.     bsr isincos
  69.     move.w d1,d0
  70.     rts
  71.  
  72.  
  73. isincos
  74.     move.w    8(sp),d0
  75.     and.w    #$3ff,d0    ; mod theta by two-pi = 1024
  76.     move.l    #_sin_tab,a0    ; load up sine table
  77.  
  78.     move.l    #quadtable,a1    ; and jump to routine to get sine, cos for quadrant
  79.     move.w    d0,d1
  80.     and.w    #$300,d1
  81.     lsr.w    #6,d1
  82.     move.l    0(a1,d1.w),a1
  83.     jsr        (a1)
  84.     rts
  85.  
  86.  
  87.     ;    polar(theta, rad, xybuf)
  88.     ;        returns cartesian equivalent to theta, rad in xybuf    
  89.     public _polar
  90.  
  91. _polar
  92.     move.w    4(sp),d0
  93.     and.w    #$3ff,d0    ; mod theta by two-pi = 1024
  94.     move.l    #_sin_tab,a0    ; load up sine table
  95.  
  96.     move.l    #quadtable,a1    ; and jump to routine to get sine, cos for quadrant
  97.     move.w    d0,d1
  98.     and.w    #$300,d1
  99.     lsr.w    #6,d1
  100.     move.l    0(a1,d1.w),a1
  101.     jsr        (a1)
  102.  
  103.     muls    6(sp),d0
  104.     asl.l #2,d0
  105.     swap d0 
  106.     muls    6(sp),d1
  107.     asl.l #2,d1
  108.     swap d1 
  109.     move.l    8(sp),a0
  110.     move.w    d1,(a0)+
  111.     move.w    d0,(a0)
  112.     rts
  113.  
  114. quad1
  115.     move.w    #256,d1
  116.     sub.w    d0,d1
  117.     add.w    d1,d1
  118.     move.w    0(a0,d1.w),d1    ;got cosine
  119.     add.w    d0,d0
  120.     move.w    0(a0,d0.w),d0    ;got sine
  121.     rts
  122.  
  123. quad2
  124.     move.w    d0,d1
  125.     neg.w    d0
  126.     add.w    #512,d0
  127.     add.w    d0,d0
  128.     move.w    0(a0,d0.w),d0    ;got sine
  129.     sub.w    #256,d1
  130.     add.w    d1,d1
  131.     move.w    0(a0,d1.w),d1    
  132.     neg.w    d1    ; got cosine
  133.     rts
  134.  
  135. quad3
  136.     move.w #3*256,d1
  137.     sub.w    d0,d1
  138.     add.w    d1,d1
  139.     move.w    0(a0,d1.w),d1    
  140.     neg.w    d1    ; got cosine
  141.     sub.w    #512,d0
  142.     add.w    d0,d0
  143.     move.w    0(a0,d0.w),d0    
  144.     neg.w    d0    ; got sine
  145.     rts
  146.  
  147. quad4
  148.     move.w    d0,d1
  149.     sub.w    #3*256,d1
  150.     add.w    d1,d1
  151.     move.w    0(a0,d1.w),d1    ; got cosine
  152.     neg.w    d0
  153.     add.w    #1024,d0
  154.     add.w    d0,d0
  155.     move.w    0(a0,d0.w),d0
  156.     neg.w    d0    ;got sine
  157.     rts
  158.  
  159.     dseg
  160. quadtable    dc.l    quad1,quad2,quad3,quad4
  161.